=======================================================================
FORM: TEST Screen [FIND BROWSE] (W5542400B)
=======================================================================
CONTROL:  BUTTON &Print Report
EVENT:  Button Clicked
-----------------------------------------------------------------------
evt_WorkStationId_JOBN
evt_TimeLastUpdated_UPMT
evt_UserId_USER
evt_DatabaseServerName_SRVR
evt_CodePath_Server_PATHCD
evt_JobQueue_JOBQUE
evt_JobstatusOW_JOBSTS
evt_ServerJobNumber_JOBNBR
evt_FoundationFutureUse2_FNDFU
evt_DatabasePath_DATP
evt_LowerCaseDBServer_SRVR
//
//
Get Audit Information
   VA evt_UserId_USER <- szUserName
   UNDEFINED X  jdDate
   VA evt_TimeLastUpdated_UPMT <- mnTime
   VA evt_WorkStationId_JOBN <- szWorkstation_UserId
//
CALL( UBE:R5542406 , Ver: TEST0001 )
   FI mnBMIID -> mnBMIID
   FI mnBMIRevisionNumber -> mnBMIRevisionNumber
   "TEST0001" X  Version

//
// Retrieve the Logged in Envt
Get Current Environment
   VA evt_CodePath_Server_PATHCD <- szEnvironmentname
//
//
// Get the OCM Mapping Server for the UBE
Fetch UBE Mapping from OCM
   "R5542406" -> szReport
   VA evt_DatabaseServerName_SRVR <- szLogicalDataSource
//
// Get the Mapping Server/Database Path on which the Job Queue fires.
F9650.Fetch Single
   VA evt_DatabaseServerName_SRVR =  TK Machine Key
   VA evt_DatabasePath_DATP <- TK Data Source
//
// Change the DatabasePath to the above.
F986110 DS OVERRIDE
   VA evt_DatabasePath_DATP -> szDatabasepath
//
VA evt_LowerCaseDBServer_SRVR = ltrim(rtrim(lower([VA evt_DatabaseServerName_SRVR]),' '),' ')
//
// Get the Job Queue of the Fired UBE
Get Default Job Queue
   VA evt_JobQueue_JOBQUE <- szJobQueue
   "R5542406" -> szReport
   "TEST0001" -> szVersion
   VA evt_UserId_USER -> szUserId
//
VA frm_ReportName_FNDFUF2 = "R5542406_TEST0001_"
//
//  Wait for Some secs, before each fetch to check if the UBE has completed
//
F986110.Select
   VA evt_JobQueue_JOBQUE =  TK Job Queue
   VA evt_CodePath_Server_PATHCD =  TK Environment Name
   VA evt_UserId_USER =  TK User ID
   SL DateToday =  TK Date - Job Submitted
   VA evt_TimeLastUpdated_UPMT <= TK Time Job Submitted
   VA evt_LowerCaseDBServer_SRVR =  TK Execution Host Name
   VA evt_WorkStationId_JOBN =  TK Origination Host Name
   SL DateToday =  TK Date - Last Activity
   VA frm_ReportName_FNDFUF2 <= TK Foundation - Future Use 2
F986110.Fetch Next
   VA evt_JobstatusOW_JOBSTS <- TK Job Status
   VA evt_ServerJobNumber_JOBNBR <- TK Server Job Number
   VA evt_FoundationFutureUse2_FNDFU <- TK Foundation - Future Use 2
While VA evt_JobstatusOW_JOBSTS is not equal to "D,E"
   Wait x seconds
      "2" -> mnReceiverWaitSeconds
   F986110.Select
      VA evt_JobQueue_JOBQUE =  TK Job Queue
      VA evt_CodePath_Server_PATHCD =  TK Environment Name
      VA evt_UserId_USER =  TK User ID
      SL DateToday =  TK Date - Job Submitted
      VA evt_TimeLastUpdated_UPMT <= TK Time Job Submitted
      VA evt_LowerCaseDBServer_SRVR =  TK Execution Host Name
      VA evt_WorkStationId_JOBN =  TK Origination Host Name
      SL DateToday =  TK Date - Last Activity
      VA frm_ReportName_FNDFUF2 <= TK Foundation - Future Use 2
   F986110.Fetch Next
      VA evt_JobstatusOW_JOBSTS <- TK Job Status
      VA evt_ServerJobNumber_JOBNBR <- TK Server Job Number
      VA evt_FoundationFutureUse2_FNDFU <- TK Foundation - Future Use 2
End While
//
// Reset the DatabasePath Override.
F986110 DS OVERRIDE
   "<Blank>" -> szDatabasepath
//
// -------------------------
// Retrieve and Show the PDF
If SV Engine_Type is equal to CO WINDOWS_ENGINE
   //
   //This gets the UBE for FAT clients.
   Print F986110
   	VA evt_ServerJobNumber_JOBNBR -> mnServerjobnumber
   	VA evt_LowerCaseDBServer_SRVR -> szExecutionhostname
   	"VW" -> szJobstatus
   	UNDEFINED X  szPortNumber
   	UNDEFINED X  szJobQueue
   	UNDEFINED X  szQueueType
   	UNDEFINED X  szToJobQueue
   	UNDEFINED X  szJobPriority
Else
   //
   //This Retrieves the Output from Server for Web/Thin Clients
   VA frm_URL = "/servlet/com.jdedwards.jas.ube?"
   VA frm_Server = "SERVER="
   VA frm_URL = concat([VA frm_URL],[VA frm_Server])
   VA frm_URL = concat([VA frm_URL],[VA evt_DatabaseServerName_SRVR])
   VA frm_Length = length([VA frm_URL])
   //
   While VA frm_Length is greater than <Zero>
      VA frm_URL = rtrim([VA frm_URL],' ')
      VA frm_Length = [VA frm_Length]-1
   End While
   //
   VA frm_URL = rtrim([VA frm_URL],' ')
   VA frm_JobNumber = "&JOBNUMBER="
   VA frm_URL = concat([VA frm_URL],[VA frm_JobNumber])
   VA frm_URL = concat([VA frm_URL],[VA evt_ServerJobNumber_JOBNBR])
   VA frm_ViewType = "&VIEWTYPE="
   VA frm_URL = concat([VA frm_URL],concat([VA frm_ViewType],"PDF"))
   Run Executable(<Blank>, VA frm_URL, "UBE", <Blank>, <Blank>, <Blank>)
End If
//
//
//

Wednesday September 16, 2009  17:10